易语言纯源码Linux复数计算

.版本 2
.支持库 eCalc

.程序集 程序集1

.子程序 _启动子程序, 整数型, , 本子程序在程序启动后最先执行

初始化 ()  ' 显示信息

返回 (0)  ' 可以根据您的需要返回任意数值


.子程序 初始化, , , 显示信息
.局部变量 复数1, 复数运算
.局部变量 复数2, 复数运算
.局部变量 实数部分, 双精度小数型
.局部变量 虚数部分, 双精度小数型
.局部变量 输入文本, 文本型

输出信息 (“************估计没几个知道复数是什么吧 (^.-)  *****************”, 1)  ' 以下是显示的信息
实数部分 ＝ 123456.25
虚数部分 ＝ 123.456
复数1.置实数 (实数部分)
复数1.置虚数 (虚数部分)
输出信息 (“复数1的实数部分：” ＋ 到文本 (实数部分), 1)
输出信息 (“复数1的虚数部分：” ＋ 到文本 (虚数部分), 1)
实数部分 ＝ 12.34
虚数部分 ＝ 56.7
复数2.置实数 (实数部分)
复数2.置虚数 (虚数部分)
输出信息 (“复数2的实数部分：” ＋ 到文本 (实数部分), 1)
输出信息 (“复数2的虚数部分：” ＋ 到文本 (虚数部分), 1)
输出信息 (“******************************”, 1)
输出信息 (“请选择下面的操作代号：”, 1)
输出信息 (“1.-------复数1和复数2相加，相减，相乘，相除”, 1)
输出信息 (“2.-------求复数1的指数，长度，极角”, 1)
输出信息 (“3.-------取复数2的实数部分和虚数部分”, 1)
输出信息 (“4.-------退出”, 1)

.判断循环首 (1 ＝ 1)  ' 以下是根据输入的数字代码调用不同的子程序
    输出信息 (“请选择代号：”, 0)
    输入文本 ＝ 标准输入 ()
    .如果真 (输入文本 ＝ “1”)
        子程序_运算1 (复数1, 复数2)  ' 复数1和复数2相加，相减，相乘，相除
    .如果真结束
    .如果真 (输入文本 ＝ “2”)
        子程序_运算2 (复数1, 复数2)  ' 求复数1的指数，长度，极角
    .如果真结束
    .如果真 (输入文本 ＝ “3”)
        子程序_运算3 (复数2)  ' 取复数2的实数部分和虚数部分
    .如果真结束
    .如果真 (输入文本 ＝ “4”)
        跳出循环 ()
    .如果真结束

.判断循环尾 ()


.子程序 子程序_运算1, , , 复数1和复数2相加，相减，相乘，相除
.参数 复数a, 复数运算
.参数 复数b, 复数运算
.局部变量 结果复数, 复数运算

结果复数 ＝ 复数b.复数相加 (复数a, 复数b)
输出信息 (“复数1和复数2的和：”, 1)
输出信息 (“实数部分：” ＋ 到文本 (结果复数.取实数 ()), 1)
输出信息 (“虚数部分：” ＋ 到文本 (结果复数.取虚数 ()), 1)

结果复数 ＝ 复数b.复数相减 (复数a, 复数b)
输出信息 (“复数1和复数2的差：”, 1)
输出信息 (“实数部分：” ＋ 到文本 (结果复数.取实数 ()), 1)
输出信息 (“虚数部分：” ＋ 到文本 (结果复数.取虚数 ()), 1)

结果复数 ＝ 复数b.复数相乘 (复数a, 复数b)
输出信息 (“复数1和复数2的积：”, 1)
输出信息 (“实数部分：” ＋ 到文本 (结果复数.取实数 ()), 1)
输出信息 (“虚数部分：” ＋ 到文本 (结果复数.取虚数 ()), 1)

结果复数 ＝ 复数b.复数相除 (复数a, 复数b)
输出信息 (“复数1和复数2的商：”, 1)
输出信息 (“实数部分：” ＋ 到文本 (结果复数.取实数 ()), 1)
输出信息 (“虚数部分：” ＋ 到文本 (结果复数.取虚数 ()), 1)

输出信息 (“”, 1)

.子程序 子程序_运算2, , , 求复数1的指数，长度，极角
.参数 复数a, 复数运算
.参数 复数b, 复数运算
.局部变量 结果复数, 复数运算
.局部变量 复数长度, 双精度小数型
.局部变量 复数极角, 双精度小数型

结果复数 ＝ 复数a.求复数指数 (复数b)
输出信息 (“复数1的指数：”, 1)
输出信息 (“实数部分：” ＋ 到文本 (结果复数.取实数 ()), 1)
输出信息 (“虚数部分：” ＋ 到文本 (结果复数.取虚数 ()), 1)

复数长度 ＝ 复数a.求复数长度 (复数a)
输出信息 (“复数1的长度：” ＋ 到文本 (复数长度), 1)

复数极角 ＝ 复数a.求复数极角 (复数a)
输出信息 (“复数1的极角：” ＋ 到文本 (复数极角), 1)

输出信息 (“”, 1)

.子程序 子程序_运算3, , , 取复数2的实数部分和虚数部分
.参数 复数b, 复数运算
.局部变量 实数部分, 双精度小数型
.局部变量 虚数部分, 双精度小数型

实数部分 ＝ 复数b.取实数 ()
虚数部分 ＝ 复数b.取虚数 ()
输出信息 (“复数2的实数部分：” ＋ 到文本 (实数部分), 1)
输出信息 (“复数2的虚数部分：” ＋ 到文本 (虚数部分), 1)
输出信息 (“”, 1)

.子程序 输出信息, , , 根据第二个参数，输出不同格式的信息
.参数 内容, 文本型
.参数 输出方式, 整数型

.如果 (输出方式 ＝ 1)
    标准输出 (, 内容 ＋ 字符 (13) ＋ 字符 (10))
.否则
    标准输出 (, 内容)
.如果结束

@林中道士