百度文库免下载劵下载源码

.版本 2
.支持库 eWord2000
.支持库 internet
.支持库 spec

.程序集 窗口程序集_启动窗口
.程序集变量 文章标题, 文本型

.子程序 _按钮1_被单击
.局部变量 分割, 文本型, , "0"
.局部变量 i, 整数型

获取内容_DOC (“wap”, 编辑框2.内容)
分割 ＝ 分割文本 (编辑框1.内容, #换行符, )
Word程序1.创建 ()
Word文档集1.置程序 (Word程序1, 真)
.计次循环首 (取数组成员数 (分割), i)
    .判断开始 (寻找文本 (分割 [i], “http://”, , 真) ＝ 1)
        Word程序1.取程序对象 ().读对象型属性 (“Selection”, ).读对象型属性 (“InlineShapes”, ).方法 (“AddPicture”, 分割 [i])
    .默认
        Word文档集1.对齐方式 ＝ 1
        Word文档集1.输入文本 (0, 分割 [i] ＋ #换行符)
    .判断结束

.计次循环尾 ()
Word文档集1.保存 (取运行目录 () ＋ “” ＋ 文章标题 ＋ “.doc”)
Word文档集1.销毁 ()
Word程序1.退出 ()
Word程序1.销毁 ()
信息框 (“提取成功”, 0, , )

.子程序 获取内容_DOC
.参数 前缀, 文本型, , wap
.参数 下载地址, 文本型
.局部变量 文本_前, 文本型
.局部变量 文本_后, 文本型
.局部变量 转换_下载地址, 文本型
.局部变量 网页代码, 文本型
.局部变量 页数, 文本型
.局部变量 文本内容, 文本型
.局部变量 页码, 整数型

' // 转换地址
文本_前 ＝ 文本_取左边 (编辑框2.内容, “wenku”)
文本_后 ＝ 文本_取右边 (编辑框2.内容, “http://”)
转换_下载地址 ＝ 文本_前 ＋ “wap” ＋ 文本_后
' =================================================
网页代码 ＝ 编码_utf8到gb2312 (到文本 (HTTP读文件 (转换_下载地址)))
页数 ＝ 文本_取出中间文本 (网页代码, “ <p class=” ＋ #引号 ＋ “page” ＋ #引号 ＋ “>”, “</p>”)
页数 ＝ 文本_取出中间文本 (页数, “/ ”, “页”)
文本内容 ＝ 文本_取出中间文本 (网页代码, “<p class=” ＋ #引号 ＋ “info” ＋ #引号 ＋ “>”, “</div>”)
文本内容 ＝ 文本_替换 (文本内容, , , 假, “<a href=” ＋ #引号, “<p class=” ＋ #引号 ＋ “txt” ＋ #引号 ＋ “>”)
文本内容 ＝ 文本_替换 (文本内容, , , 假, “target=”, “</p>”)
.判断开始 (页数 ＝ “1”)
    内容提取 (文本内容)
.默认
    .计次循环首 (到整数 (页数), 页码)
        网页代码 ＝ 编码_utf8到gb2312 (网页_取网页源码 (转换_下载地址 ＋ “?pn=” ＋ 到文本 (页码) ＋ “&pu=”))
        文本内容 ＝ 文本_取出中间文本 (网页代码, “<div class=” ＋ #引号 ＋ “content bgcolor1” ＋ #引号 ＋ “>”, “<p class=” ＋ #引号 ＋ “page” ＋ #引号 ＋ “>”)
        文本内容 ＝ 文本_替换 (文本内容, , , 假, “<a href=” ＋ #引号, “<p class=” ＋ #引号 ＋ “txt” ＋ #引号 ＋ “>”)
        文本内容 ＝ 文本_替换 (文本内容, , , 假, “target=” ＋ #引号, “</p>”)
        内容提取 (文本内容)
    .计次循环尾 ()
.判断结束
文章标题 ＝ 文本_取出中间文本 (网页代码, “<title>”, “</title>”)

.子程序 内容提取, 整数型, , 本子程序采用【精易编程助手】生成。成功返回匹配的数量，失败返回0。
.参数 源文本, 文本型, , 欲被匹配的文本
.局部变量 局_正则, 正则表达式类, , , 此类为精易模块里面的正则类，精易模块下载地址：www.3600gz.cn/thread-1177-1-1.html
.局部变量 局_匹配数, 整数型
.局部变量 局_计次, 整数型

.如果真 (局_正则.创建 (“<p class=” ＋ #引号 ＋ “txt” ＋ #引号 ＋ “>(.*?)</p>”, 源文本, 假, 真, 真) ＝ 假)
    信息框 (“正则创建失败，请检查正则表达式语句是否有误！”, #错误图标, , )
    返回 (0)
.如果真结束
局_匹配数 ＝ 局_正则.取匹配数量 ()
.如果真 (局_匹配数 ＝ 0)
    信息框 (“匹配失败，请检检查正则语句是否有误，数量：0”, #错误图标, , )
    返回 (0)
.如果真结束
.计次循环首 (局_匹配数, 局_计次)
    编辑框1.加入文本 (局_正则.取子匹配文本 (局_计次, 1), #换行符)
    调试输出 (局_正则.取子匹配文本 (局_计次, 1))
.计次循环尾 ()
返回 (局_匹配数)

@飞机君