批量公开常量 dll 数据类型易语言源码

批量公开常量 dll 数据类型易语言源码

@福仔

.版本 2

.程序集 窗口程序集_启动窗口
.程序集变量 程序集_文件数据, 文本型

.子程序 __启动窗口_创建完毕



.子程序 公开DLL, 文本型
.参数 数据, 文本型
.局部变量 分割, 文本型, , "0"
.局部变量 成员数, 整数型
.局部变量 i, 整数型
.局部变量 文本, 文本型
.局部变量 临时, 文本型

文本 ＝ “.版本 2” ＋ #换行符 ＋ #换行符
.判断开始 (取文本左边 (数据, 取文本长度 (文本)) ＝ 文本)
    临时 ＝ 取文本右边 (数据, 取文本长度 (数据) － 取文本长度 (文本))
.默认
    临时 ＝ 数据
.判断结束
文本 ＝ “”
.如果真 (取文本左边 (临时, 8) ≠ “.DLL命令”)
    返回 (“”)
.如果真结束
分割 ＝ 分割文本 (临时, #换行符 ＋ #换行符, )
成员数 ＝ 取数组成员数 (分割)
.计次循环首 (成员数, i)
    .' 如果真 (i ＝ 成员数)
        ' 暂停 ()
    .如果真结束
    文本 ＝ 文本 ＋ 处理dll (分割 [i]) ＋ #换行符
.计次循环尾 ()
分割 ＝ 分割文本 (文本, #换行符 ＋ #换行符, )
标题 ＝ “处理前DLL命令数：” ＋ 到文本 (成员数) ＋ “，处理后DLL命令数：” ＋ 到文本 (取数组成员数 (分割))
文本 ＝ “.版本 2” ＋ #换行符 ＋ #换行符 ＋ 文本
返回 (文本)


.子程序 处理dll, 文本型
.参数 文本, 文本型
.局部变量 分割, 文本型, , "0"
.局部变量 成员数, 整数型
.局部变量 i, 整数型
.局部变量 结果, 文本型
.局部变量 寻找位置, 整数型
.局部变量 局部_左边部分, 文本型
.局部变量 分割1, 文本型, , "0"

分割 ＝ 分割文本 (文本, #换行符, )
成员数 ＝ 取数组成员数 (分割)

分割1 ＝ 分割文本 (分割 [1], “,”, )
成员数 ＝ 取数组成员数 (分割1)
' .DLL命令 DLL命令名, 返回值, 库路径, 库中命令名, 公开, 备注
.判断开始 (成员数 ＝ 1)  ' 没有返回值,没有公开,没有备注
    结果 ＝ 分割1 [1] ＋ “, , , , 公开” ＋ #换行符
    .计次循环首 (取数组成员数 (分割) － 1, i)
        结果 ＝ 结果 ＋ 分割 [i ＋ 1] ＋ #换行符
    .计次循环尾 ()

.判断 (成员数 ＝ 2)  ' 只有返回值
    结果 ＝ 分割1 [1] ＋ “, ” ＋ 分割1 [2] ＋ “, , , 公开” ＋ #换行符
    .计次循环首 (取数组成员数 (分割) － 1, i)
        结果 ＝ 结果 ＋ 分割 [i ＋ 1] ＋ #换行符
    .计次循环尾 ()

.判断 (成员数 ＝ 4)
    结果 ＝ 分割1 [1] ＋ “, ” ＋ 分割1 [2] ＋ “, ” ＋ 分割1 [3] ＋ “, , 公开” ＋ #换行符
    .计次循环首 (取数组成员数 (分割) － 1, i)
        结果 ＝ 结果 ＋ 分割 [i ＋ 1] ＋ #换行符
    .计次循环尾 ()

.判断 (成员数 ＝ 5)  ' 有公开或者库命令或者库文件名
    结果 ＝ 分割1 [1] ＋ “, ” ＋ 分割1 [2] ＋ “, ” ＋ 分割1 [3] ＋ “, ” ＋ 分割1 [4] ＋ “, 公开” ＋ #换行符
    .计次循环首 (取数组成员数 (分割) － 1, i)
        结果 ＝ 结果 ＋ 分割 [i ＋ 1] ＋ #换行符
    .计次循环尾 ()

.判断 (成员数 ≥ 6)  ' 有备注
    结果 ＝ 分割1 [1] ＋ “, ” ＋ 分割1 [2] ＋ “, ” ＋ 分割1 [3] ＋ “, ” ＋ 分割1 [4] ＋ “, 公开, ”
    .变量循环首 (6, 成员数, 1, i)
        .判断开始 (i ＝ 成员数)
            结果 ＝ 结果 ＋ 分割1 [i] ＋ #换行符
        .默认
            结果 ＝ 结果 ＋ 分割1 [i] ＋ “,”
        .判断结束


    .变量循环尾 ()
    .计次循环首 (取数组成员数 (分割) － 1, i)
        结果 ＝ 结果 ＋ 分割 [i ＋ 1] ＋ #换行符
    .计次循环尾 ()

.默认
    返回 (文本 ＋ #换行符)
.判断结束

返回 (结果)
.计次循环首 (4, i)
    寻找位置 ＝ 寻找文本 (分割 [1], “,”, 寻找位置 ＋ 1, 假)
.计次循环尾 ()
.判断开始 (寻找位置 ＝ -1)
    结果 ＝ 分割 [1] ＋ “, 公开” ＋ #换行符
    .计次循环首 (成员数 － 1, i)
        结果 ＝ 结果 ＋ 分割 [i ＋ 1] ＋ #换行符
    .计次循环尾 ()
.默认
    结果 ＝ 取文本中间 (分割 [1], 寻找位置 ＋ 2, 取文本长度 (分割 [1]) － 寻找位置)
    局部_左边部分 ＝ 取文本左边 (分割 [1], 寻找位置 ＋ 1)

    .如果真 (删全部空 (结果) ≠ “”)
        .判断开始 (取文本左边 (删全部空 (结果), 4) ＝ “公开”)
            结果 ＝ 文本 ＋ #换行符
        .默认
            结果 ＝ 局部_左边部分 ＋ “公开” ＋ 结果 ＋ #换行符
            .计次循环首 (成员数 － 1, i)
                结果 ＝ 结果 ＋ 分割 [i ＋ 1] ＋ #换行符
            .计次循环尾 ()

        .判断结束

    .如果真结束

.判断结束



返回 (结果)

.子程序 公开常量, 文本型
.参数 数据, 文本型
.局部变量 文本, 文本型
.局部变量 临时, 文本型
.局部变量 分割, 文本型, , "0"
.局部变量 成员数, 整数型
.局部变量 i, 整数型

文本 ＝ “.版本 2” ＋ #换行符 ＋ #换行符
.判断开始 (取文本左边 (数据, 取文本长度 (文本)) ＝ 文本)
    临时 ＝ 取文本右边 (数据, 取文本长度 (数据) － 取文本长度 (文本))
.默认
    临时 ＝ 数据
.判断结束
文本 ＝ “”
.如果真 (取文本左边 (临时, 5) ≠ “.常量”)
    返回 (“”)
.如果真结束
' 临时 ＝ 子文本替换 (临时, #换行符 ＋ #换行符, #换行符, , , 真)
分割 ＝ 分割文本 (临时, #换行符, )
成员数 ＝ 取数组成员数 (分割)
.计次循环首 (成员数, i)
    文本 ＝ 文本 ＋ 处理常量 (分割 [i])
.计次循环尾 ()
分割 ＝ 分割文本 (文本, #换行符, )
标题 ＝ “处理前常量数：” ＋ 到文本 (成员数) ＋ “，处理后常量数：” ＋ 到文本 (取数组成员数 (分割))
文本 ＝ “.版本 2” ＋ #换行符 ＋ #换行符 ＋ 文本
返回 (文本)

.子程序 处理常量, 文本型
.参数 文本, 文本型
.局部变量 结果, 文本型
.局部变量 分割, 文本型, , "0"
.局部变量 成员数, 整数型

.如果真 (文本 ＝ “”)
    返回 (#换行符)
.如果真结束
分割 ＝ 分割文本 (文本, “,”, )
成员数 ＝ 取数组成员数 (分割)

.判断开始 (成员数 ＝ 2)
    结果 ＝ 分割 [1] ＋ “, ” ＋ 分割 [2] ＋ “, 公开”
.判断 (成员数 ＝ 3)
    返回 (文本 ＋ #换行符)
.判断 (成员数 ＝ 4)
    结果 ＝ 分割 [1] ＋ “, ” ＋ 分割 [2] ＋ “, 公开, ” ＋ 分割 [4]
.默认

.判断结束
' .常量 常量4, "“2”"
' .常量 常量3, "1"
' .常量 常量3, "1", 公开
' .常量 常量4, "“2”", 公开
' .常量 常量4, "“2”", , 备注
返回 (结果 ＋ #换行符)


.子程序 _按钮_常量_被单击
.局部变量 结果, 文本型

.如果真 (编辑框1.内容 ＝ “”)
    信息框 (“没有数据”, 0, , )
    返回 ()
.如果真结束
结果 ＝ 公开常量 (编辑框1.内容)
.如果真 (结果 ＝ “”)
    信息框 (“数据可能不是常量数据,请检查”, 0, , )
    返回 ()
.如果真结束
编辑框1.内容 ＝ 结果

.子程序 _按钮_dll_被单击
.局部变量 结果, 文本型

.如果真 (编辑框1.内容 ＝ “”)
    信息框 (“没有数据”, 0, , )
    返回 ()
.如果真结束
结果 ＝ 公开DLL (编辑框1.内容)
.如果真 (结果 ＝ “”)
    信息框 (“数据可能不是DLL数据,请检查”, 0, , )
    返回 ()
.如果真结束
编辑框1.内容 ＝ 结果

.子程序 _按钮_数据类型_被单击
.局部变量 结果, 文本型

.如果真 (编辑框1.内容 ＝ “”)
    信息框 (“没有数据”, 0, , )
    返回 ()
.如果真结束
结果 ＝ 公开数据类型 (编辑框1.内容)
.如果真 (结果 ＝ “”)
    信息框 (“数据可能不是数据类型结构,请检查”, 0, , )
    返回 ()
.如果真结束
编辑框1.内容 ＝ 结果


.子程序 公开数据类型, 文本型
.参数 数据, 文本型
.局部变量 文本, 文本型
.局部变量 临时, 文本型
.局部变量 分割, 文本型, , "0"
.局部变量 成员数, 整数型
.局部变量 i, 整数型

文本 ＝ “.版本 2” ＋ #换行符 ＋ #换行符
.判断开始 (取文本左边 (数据, 取文本长度 (文本)) ＝ 文本)
    临时 ＝ 取文本右边 (数据, 取文本长度 (数据) － 取文本长度 (文本))
.默认
    临时 ＝ 数据
.判断结束
文本 ＝ “”
.如果真 (取文本左边 (临时, 9) ≠ “.数据类型”)
    返回 (“”)
.如果真结束
分割 ＝ 分割文本 (临时, #换行符 ＋ #换行符, )
成员数 ＝ 取数组成员数 (分割)
.计次循环首 (成员数, i)
    文本 ＝ 文本 ＋ 处理数据类型 (分割 [i]) ＋ #换行符
.计次循环尾 ()


分割 ＝ 分割文本 (文本, #换行符 ＋ #换行符, )
标题 ＝ “处理前数据类型数量：” ＋ 到文本 (成员数) ＋ “，处理后数据类型数量：” ＋ 到文本 (取数组成员数 (分割))
文本 ＝ “.版本 2” ＋ #换行符 ＋ #换行符 ＋ 文本
返回 (文本)


.子程序 处理数据类型, 文本型
.参数 文本, 文本型
.局部变量 分割, 文本型, , "0"
.局部变量 分割1, 文本型, , "0"
.局部变量 成员数, 整数型
.局部变量 结果, 文本型
.局部变量 i, 整数型

分割 ＝ 分割文本 (文本, #换行符, )

分割1 ＝ 分割文本 (分割 [1], “,”, )
成员数 ＝ 取数组成员数 (分割1)
.判断开始 (成员数 ＝ 1)
    结果 ＝ 分割 [1] ＋ “, 公开” ＋ #换行符
    .计次循环首 (取数组成员数 (分割) － 1, i)
        结果 ＝ 结果 ＋ 分割 [i ＋ 1] ＋ #换行符
    .计次循环尾 ()

.判断 (成员数 ＝ 2)
    返回 (文本 ＋ #换行符)
.判断 (成员数 ＝ 3)
    结果 ＝ 分割1 [1] ＋ “, 公开,” ＋ 分割1 [3] ＋ #换行符
    .计次循环首 (取数组成员数 (分割) － 1, i)
        结果 ＝ 结果 ＋ 分割 [i ＋ 1] ＋ #换行符
    .计次循环尾 ()

.默认

.判断结束
返回 (结果)

.子程序 _按钮1_被单击
.局部变量 路径, 文本型

路径 ＝ 对话框_打开文件 (取窗口句柄 (), 取运行目录 (), , “文本文件|*.txt”, )
.如果真 (路径 ＝ “”)
    返回 ()
.如果真结束
程序集_文件数据 ＝ 到文本 (读入文件 (路径))
编辑框1.内容 ＝ 程序集_文件数据

.子程序 _按钮2_被单击

.如果真 (编辑框1.内容 ＝ “”)
    信息框 (“没有数据”, 0, , )
    返回 ()
.如果真结束
置剪辑板文本 (编辑框1.内容)

.子程序 _按钮3_被单击

编辑框1.内容 ＝ 程序集_文件数据

.子程序 _编辑框1_字符输入, 整数型
.参数 字符代码, 整数型

.如果真 (字符代码 ＝ 22)
    程序集_文件数据 ＝ 取剪辑板文本 ()
.如果真结束