独立cookies模块源码

独立cookies模块源码，

调用例程：多进程同时填表源码-独立Cookies-易语言例程-三叶资源网 https://www.iisanye.com/?id=12381

@宇智波·晓易

.版本 2
.支持库 shell
.支持库 spec

.子程序 独立Cookies, 整数型, 公开, 返回编号
.参数 互斥体, 文本型
.局部变量 j, 整数型
.局部变量 handle, 整数型
.局部变量 getpatha, 整数型
.局部变量 getpathw, 整数型
.局部变量 shell32, 整数型

.计次循环首 (123456, j)
    handle ＝ CreateMutexA (0, 1, 互斥体 ＋ 到文本 (j))
    .如果 (GetLastError () ＝ #ERROR_ALREADY_EXISTS)
        CloseHandle (handle)
    .否则
        index ＝ j
        new ＝ 取特定目录 (11) ＋ “xiaoyi\only1cookies_” ＋ 到文本 (index)
        跳出循环 ()
    .如果结束

.计次循环尾 ()
shell32 ＝ LoadLibraryA (“shell32.dll”)
getpatha ＝ GetProcAddress (shell32, “SHGetFolderPathA”)
getpathw ＝ GetProcAddress (shell32, “SHGetFolderPathW”)
oldpatha ＝ VirtualAlloc (0, 4096, 4096, 64)
oldpathw ＝ oldpatha ＋ 10
RtlMoveMemory (oldpatha, getpatha, 5)
RtlMoveMemory (oldpathw, getpathw, 5)
写到内存 (jmpcode (oldpatha ＋ 5, getpatha ＋ 5), oldpatha ＋ 5, )
写到内存 (jmpcode (oldpathw ＋ 5, getpathw ＋ 5), oldpathw ＋ 5, )
WriteProcessMemory (-1, getpatha, jmpcode (getpatha, 到整数 (&mygetpatha)), 5, 0)
WriteProcessMemory (-1, getpathw, jmpcode (getpathw, 到整数 (&mygetpathw)), 5, 0)
返回 (j)

.子程序 jmpcode, 字节集
.参数 地址, 整数型
.参数 目标地址, 整数型
.局部变量 a, 整数型

a ＝ 目标地址 － 地址 － 5
返回 ({ 233 } ＋ 到字节集 (a))

.子程序 mygetpatha, 整数型
.参数 hwndOwner, 整数型
.参数 nFolder, 整数型
.参数 hToken, 整数型
.参数 dwFlags, 整数型
.参数 pszPath, 整数型
.局部变量 ret, 整数型

.判断开始 (位与 (nFolder, #CSIDL_COOKIES) ＝ #CSIDL_COOKIES)
    写到内存 (new, pszPath, )
    返回 (0)
.默认
    ' 本源码来自三叶资源网(www.sanye.cx)
.判断结束
调用子程序 (oldpatha, , ret, hwndOwner, nFolder, hToken, dwFlags, pszPath)
返回 (ret)

.子程序 mygetpathw, 整数型
.参数 hwndOwner, 整数型
.参数 nFolder, 整数型
.参数 hToken, 整数型
.参数 dwFlags, 整数型
.参数 pszPath, 整数型
.局部变量 ret, 整数型

.判断开始 (位与 (nFolder, #CSIDL_COOKIES) ＝ #CSIDL_COOKIES)
    写到内存 (AnsiToUnicode (new), pszPath, )
    返回 (0)
.默认

.判断结束
调用子程序 (oldpathw, , ret, hwndOwner, nFolder, hToken, dwFlags, pszPath)
返回 (ret)

.子程序 AnsiToUnicode, 字节集
.参数 ansi, 文本型
.局部变量 unicode, 字节集
.局部变量 needlong, 整数型

needlong ＝ MultiByteToWideChar (0, 0, ansi, -1, {  }, 0)
.如果真 (needlong ＞ 0)
    unicode ＝ 取空白字节集 (needlong × 2)
    MultiByteToWideChar (0, 0, ansi, -1, unicode, needlong × 2)
.如果真结束
返回 (unicode)