易语言调用阿里云API新闻头条例程

.版本 2
.支持库 spec
.支持库 internet

.程序集 窗口程序集_启动窗口
.程序集变量 新闻, 类_新闻, , "0"

.子程序 _按钮1_被单击
.局部变量 类型, 文本型

.如果真 (编辑框_AppCode.内容 ＝ “”)
    信息框 (“请输入AppCode！”, 0, , )
    返回 ()
.如果真结束

.判断开始 (单选框_头条.选中 ＝ 真)
    类型 ＝ “top”
.判断 (单选框_社会.选中 ＝ 真)
    类型 ＝ “shehui”
.判断 (单选框_国内.选中 ＝ 真)
    类型 ＝ “guonei”
.判断 (单选框_国际.选中 ＝ 真)
    类型 ＝ “guoji”
.判断 (单选框_娱乐.选中 ＝ 真)
    类型 ＝ “yule”
.判断 (单选框_体育.选中 ＝ 真)
    类型 ＝ “tiyu”
.判断 (单选框_军事.选中 ＝ 真)
    类型 ＝ “junshi”
.判断 (单选框_科技.选中 ＝ 真)
    类型 ＝ “keji”
.判断 (单选框_财经.选中 ＝ 真)
    类型 ＝ “caijing”
.判断 (单选框_时尚.选中 ＝ 真)
    类型 ＝ “shishang”
.默认

.判断结束
获取 (类型)

.子程序 获取
.参数 类型, 文本型
.局部变量 url, 文本型
.局部变量 json, 文本型
.局部变量 json操作, 类_json
.局部变量 局_计次, 整数型
.局部变量 局_欲加入的成员, 类_新闻
.局部变量 局_成员数, 整数型

组合框1.清空 ()
url ＝ “http://toutiao-ali.juheapi.com/toutiao/index?” ＋ “type=” ＋ 类型
调试输出 (url)
json ＝ 编码_Utf8到Ansi (网页_访问 (url, 0, , , , “Authorization:APPCODE ” ＋ 编辑框_AppCode.内容, , , , ))
调试输出 (json)
json操作.解析 (json)
局_成员数 ＝ json操作.成员数 (“result.data”)
.如果真 (局_成员数 ＝ 0)
    信息框 (“失败！”, 0, , )
    返回 ()
.如果真结束

.计次循环首 (局_成员数, 局_计次)
    ' 加入成员 (新闻 [局_计次].标题, json操作.取通用属性 (“result.data[” ＋ 到文本 (局_计次 － 1) ＋ “].title”, ))
    局_欲加入的成员.标题 ＝ json操作.取通用属性 (“result.data[” ＋ 到文本 (局_计次 － 1) ＋ “].title”, )
    局_欲加入的成员.时间 ＝ json操作.取通用属性 (“result.data[” ＋ 到文本 (局_计次 － 1) ＋ “].date”, )
    局_欲加入的成员.作者 ＝ json操作.取通用属性 (“result.data[” ＋ 到文本 (局_计次 － 1) ＋ “].author_name”, )
    局_欲加入的成员.URL ＝ json操作.取通用属性 (“result.data[” ＋ 到文本 (局_计次 － 1) ＋ “].url”, )
    局_欲加入的成员.图片 ＝ json操作.取通用属性 (“result.data[” ＋ 到文本 (局_计次 － 1) ＋ “].thumbnail_pic_s”, )
    加入成员 (新闻, 局_欲加入的成员)
    组合框1.加入项目 (到文本 (局_计次) ＋ “.” ＋ 局_欲加入的成员.标题, )
.计次循环尾 ()
组合框1.现行选中项 ＝ 0
_组合框1_列表项被选择 ()
json操作.清除 ()

.子程序 _组合框1_列表项被选择

编辑框_标题.内容 ＝ 新闻 [组合框1.现行选中项 ＋ 1].标题
编辑框_时间.内容 ＝ 新闻 [组合框1.现行选中项 ＋ 1].时间
编辑框_作者.内容 ＝ 新闻 [组合框1.现行选中项 ＋ 1].作者
编辑框_URL.内容 ＝ 新闻 [组合框1.现行选中项 ＋ 1].URL
图片框1.图片 ＝ HTTP读文件 (新闻 [组合框1.现行选中项 ＋ 1].图片)

@爱死你巴掌