QQ/微信群发源码

部分代码：

.版本 2
.支持库 iext
.支持库 spec

.程序集 窗口程序集_启动窗口

.子程序 _按钮_刷新窗口_被单击
.局部变量 QQ子窗口, 整数型, , "0"
.局部变量 微信子窗口, 整数型, , "0"
.局部变量 n1, 整数型
.局部变量 sy, 整数型

超级列表框_qq窗口.全部删除 ()
超级列表框_微信窗口.全部删除 ()
窗口_枚举出当前打开的窗口 (QQ子窗口, 微信子窗口)
.计次循环首 (取数组成员数 (QQ子窗口), n1)
    sy ＝ 超级列表框_qq窗口.插入表项 (, 窗口_取标题 (QQ子窗口 [n1]), , , , )
    超级列表框_qq窗口.置标题 (sy, 1, 到文本 (QQ子窗口 [n1]))
.计次循环尾 ()
.计次循环首 (取数组成员数 (微信子窗口), n1)
    sy ＝ 超级列表框_微信窗口.插入表项 (, 窗口_取标题 (微信子窗口 [n1]), , , , )
    超级列表框_微信窗口.置标题 (sy, 1, 到文本 (微信子窗口 [n1]))
.计次循环尾 ()

.子程序 _按钮_开始发送_被单击
.局部变量 n1, 整数型

按钮_开始发送.禁止 ＝ 真
.计次循环首 (超级列表框_qq窗口.取表项数 (), n1)
    .如果真 (超级列表框_qq窗口.取当前状态图片 (n1 － 1) ＝ 1)
        操作_发送内容 (到整数 (超级列表框_qq窗口.取标题 (n1 － 1, 1)), 编辑框1.内容, 1)
    .如果真结束

.计次循环尾 ()
.计次循环首 (超级列表框_微信窗口.取表项数 (), n1)
    .如果真 (超级列表框_微信窗口.取当前状态图片 (n1 － 1) ＝ 1)
        操作_发送内容 (到整数 (超级列表框_微信窗口.取标题 (n1 － 1, 1)), 编辑框1.内容, 2)
    .如果真结束

.计次循环尾 ()
按钮_开始发送.禁止 ＝ 假

.子程序 操作_发送内容
.参数 句柄, 整数型
.参数 内容, 文本型
.参数 类型, 整数型, , 1为qq,2为微信
.局部变量 矩形, 精易_矩形

.如果 (类型 ＝ 1)
    .循环判断首 ()
        窗口_还原 (句柄)
        窗口_置焦点 (句柄)
    .循环判断尾 (窗口_是否在屏幕内 (句柄, 假) ≠ 真)
    置剪辑板文本 (内容)
    键盘_组合按键 (#V键, #Ctrl键)
    程序_延时 (300)
    .计次循环首 (10, )
        键盘_组合按键 (#S键, #Alt键)
    .计次循环尾 ()
    程序_延时 (1000)
    .循环判断首 ()
        窗口_最小化 (句柄)
    .循环判断尾 (窗口_是否在屏幕内 (句柄, 假) ＝ 真)
.否则
    .如果 (类型 ＝ 2)
        窗口_还原 (句柄)
        程序_延时 (100)
        窗口_置焦点 (句柄)
        程序_延时 (500)
        置剪辑板文本 (内容)
        矩形 ＝ 窗口_取位置和大小 (句柄)
        .计次循环首 (10, )
            ' 鼠标_移动 (句柄, 50, 矩形.底边 － 80)
            鼠标_单击 (句柄, 50, 矩形.底边 － 80)
        .计次循环尾 ()
        程序_延时 (300)
        键盘_组合按键 (#V键, #Ctrl键)
        程序_延时 (300)
        .计次循环首 (10, )
            键盘_组合按键 (#S键, #Alt键)
        .计次循环尾 ()
        ' 窗口_置状态 (句柄, 7)
        程序_延时 (300)
        窗口_最小化 (句柄)
        ' 程序_延时 (1000)
    .否则

    .如果结束

.如果结束


.子程序 窗口_枚举出当前打开的窗口
.参数 腾讯好友窗口, 整数型, 数组
.参数 微信窗口, 整数型, 数组
.局部变量 子窗口, 整数型, , "0"
.局部变量 n1, 整数型
.局部变量 矩形, 精易_矩形
.局部变量 宽, 整数型
.局部变量 高, 整数型

窗口_模糊遍历窗口 (, “TXGuiFoundation”, , 子窗口)
.计次循环首 (取数组成员数 (子窗口), n1)
    矩形 ＝ 窗口_取位置和大小 (子窗口 [n1])
    宽 ＝ 矩形.右边
    高 ＝ 矩形.底边
    .如果真 (窗口_取父句柄 (子窗口 [n1]) ＝ 0 且 窗口_取祖句柄 (子窗口 [n1]) ＝ 子窗口 [n1] 且 宽 ＞ 高 且 窗口_取标题 (子窗口 [n1]) ≠ “”)
        加入成员 (腾讯好友窗口, 子窗口 [n1])
    .如果真结束

.计次循环尾 ()
窗口_模糊遍历窗口 (, “ChatWnd”, , 子窗口)
.计次循环首 (取数组成员数 (子窗口), n1)
    .如果真 (窗口_取父句柄 (子窗口 [n1]) ＝ 0 且 窗口_取祖句柄 (子窗口 [n1]) ＝ 子窗口 [n1] 且 窗口_取标题 (子窗口 [n1]) ≠ “”)
        调试输出 (窗口_取标题 (子窗口 [n1]))
        加入成员 (微信窗口, 子窗口 [n1])
    .如果真结束

.计次循环尾 ()

@cfljm1