精易担保系统接单助手

.版本 2
.支持库 iext
.支持库 spec

.程序集 窗口程序集_启动窗口
.程序集变量 订单标题, 文本型, , "0"
.程序集变量 预算价格, 文本型, , "0"
.程序集变量 是否需要源码, 文本型, , "0"
.程序集变量 发布时间, 文本型, , "0"
.程序集变量 下单方, 文本型, , "0"
.程序集变量 thread, 文本型, , "0"
.程序集变量 tid, 文本型, , "0"

.子程序 __启动窗口_创建完毕
.局部变量 i, 整数型
.局部变量 个数, 整数型
.局部变量 页数, 文本型

取订单 (页数, 1, 订单标题, 预算价格, 是否需要源码, 下单方, 发布时间, thread, tid)
透明标签_页数.标题 ＝ “共 ” ＋ 页数 ＋ “页”
.计次循环首 (取数组成员数 (订单标题), i)
    个数 ＝ 超级列表框1.取表项数 ()
    超级列表框1.插入表项 (个数, 到文本 (个数 ＋ 1), , , , )
    超级列表框1.置标题 (个数, 1, 订单标题 [i])
    超级列表框1.置标题 (个数, 2, 预算价格 [i])
    超级列表框1.置标题 (个数, 3, 是否需要源码 [i])
    超级列表框1.置标题 (个数, 4, 下单方 [i])
    超级列表框1.置标题 (个数, 5, 发布时间 [i])
    超级列表框1.置标题 (个数, 6, thread [i])
    超级列表框1.置标题 (个数, 7, tid [i])
.计次循环尾 ()

.子程序 取订单
.参数 总页数, 文本型, 可空
.参数 页数序号, 整数型, 可空, 第几页
.参数 订单标题, 文本型, 可空 数组, 为数组
.参数 预算价格, 文本型, 可空 数组, 为数组
.参数 是否需要源码, 文本型, 可空 数组, 为数组
.参数 下单方, 文本型, 可空 数组, 为数组
.参数 发布时间, 文本型, 可空 数组, 为数组
.参数 thread, 文本型, 可空 数组, 用于访问订单
.参数 tid, 文本型, 可空 数组, 用于联系下单方
.局部变量 结果, 文本型
.局部变量 分割, 文本型, , "0"
.局部变量 i, 整数型
.局部变量 发布时间1, 文本型

结果 ＝ 到文本 (网页_访问 (“http://bbs.125.la/plugin.php?id=e3600%3Atask&mod=show&type=1&page=” ＋ 到文本 (页数序号) ＋ “&a=1486905630414”, , , cookie))
总页数 ＝ 文本_取出中间文本 (结果, “共 ”, “ 页”)
调试输出 (总页数)
结果 ＝ 文本_取出中间文本 (结果, “联系下单方”, “multipage”)
分割 ＝ 分割文本 (结果, #分隔符, )
删除成员 (分割, 1, 1)
.计次循环首 (取数组成员数 (分割), i)
    结果 ＝ 分割 [i]
    加入成员 (订单标题, 文本_取出中间文本 (结果, #账单标题前, #预算价格前))
    加入成员 (预算价格, 文本_取出中间文本 (结果, #预算价格前, #是否需要源码前))
    加入成员 (是否需要源码, 文本_取出中间文本 (结果, #是否需要源码前, #发布时间前))
    发布时间1 ＝ 文本_取出中间文本 (结果, #发布时间前, #发布时间后)
    发布时间1 ＝ 子文本替换 (发布时间1, “ ”, “”, , , 真)
    发布时间1 ＝ 文本_取右边 (发布时间1, #发布时间中)
    加入成员 (发布时间, 发布时间1)
    文本_取出中间文本 (结果, #下单方前, #下单方后)
    加入成员 (下单方, 文本_取右边 (文本_取出中间文本 (结果, #下单方前, #下单方后), #下单方前))
    加入成员 (thread, 文本_取出中间文本 (结果, #thread前, #thread后))
    加入成员 (tid, 文本_取出中间文本 (结果, #下单方后, #thread前))
.计次循环尾 ()
' \" target=\"_blank\">能过UA的找我  价格可以谈</a></td><td><font color=#FF6600><b>￥2000</b></font></td><td>不需要</td><td><span title=\"2017-2-12 21:25\">9&nbsp;分钟前</span></td><td>2017-02-17</td><td><a href=\"home.php?mod=space&uid=378257\" target=\"_blank\">15105105769</a></td><td><a href=\"forum.php?mod=viewthread&tid=13984151\" target=\"_blank\">点击联系</a></td></tr><tr><td><a href=\"thread-13984150-1-1.html\" title=\"

.子程序 _超级列表框1_右键单击表项

弹出菜单 (右键菜单, , )

.子程序 _按钮_跳转_被单击
.局部变量 i, 整数型
.局部变量 个数, 整数型
.局部变量 页数, 文本型

超级列表框1.全部删除 ()
清空数组 ()
取订单 (页数, 到整数 (编辑框_页数.内容), 订单标题, 预算价格, 是否需要源码, 下单方, 发布时间, thread, tid)
.计次循环首 (取数组成员数 (订单标题), i)
    个数 ＝ 超级列表框1.取表项数 ()
    超级列表框1.插入表项 (个数, 到文本 (个数 ＋ 1), , , , )
    超级列表框1.置标题 (个数, 1, 订单标题 [i])
    超级列表框1.置标题 (个数, 2, 预算价格 [i])
    超级列表框1.置标题 (个数, 3, 是否需要源码 [i])
    超级列表框1.置标题 (个数, 4, 下单方 [i])
    超级列表框1.置标题 (个数, 5, 发布时间 [i])
    超级列表框1.置标题 (个数, 6, thread [i])
    超级列表框1.置标题 (个数, 7, tid [i])
.计次循环尾 ()

.子程序 快速回复, 逻辑型, 公开
.参数 tid1, 文本型
.参数 回复内容, 文本型
.局部变量 结果, 文本型
.局部变量 value, 文本型
.局部变量 内容, 文本型
.局部变量 tid2, 文本型
.局部变量 cook, 文本型

内容 ＝ 编码_URL编码 (回复内容, 真, 假)
结果 ＝ 到文本 (网页_访问 (“http://bbs.125.la/” ＋ tid1, 0, , cookie))
tid2 ＝ 文本_取右边 (tid1, “&tid=”, )
value ＝ 文本_取出中间文本 (结果, #value前, #value后)
结果 ＝ 到文本 (网页_访问 (“http://bbs.125.la/forum.php?mod=post&action=reply&fid=169&tid=” ＋ tid2 ＋ “&extra=page%3D1&replysubmit=yes&infloat=yes&handlekey=fastpost&inajax=1”, 1, “message=” ＋ 内容 ＋ “&posttime=” ＋ value ＋ “&formhash=” ＋ formhash ＋ “&usesig=&subject=++”, cookie, ))
.如果 (寻找文本 (结果, “回复发布成功”, , 假) ≠ -1)
    结果 ＝ 到文本 (网页_访问 (“http://bbs.125.la/plugin.php?id=e3600&mod=xiadan&ac=viewlink1&infloat=yes&handlekey=showmsg_318911&inajax=1&ajaxtarget=fwin_content_viewlink”, 0, , cookie))
    返回 (真)
.否则
    返回 (假)
.如果结束


.子程序 清空数组

清除数组 (订单标题)
清除数组 (预算价格)
清除数组 (是否需要源码)
清除数组 (下单方)
清除数组 (发布时间)
清除数组 (thread)
清除数组 (tid)

.子程序 _快速回复接单_被选择

载入 (窗口1, , 真)

.子程序 _按钮_登陆_被单击
.局部变量 账号, 文本型
.局部变量 JS, 类_脚本组件
.局部变量 密码, 文本型
.局部变量 结果, 文本型
.局部变量 账户信息, 文本型, , "0"
.局部变量 正则, 正则表达式类
.局部变量 i, 整数型

账号 ＝ 编码_URL编码 (编辑框_账号.内容, 真, 假)
JS.执行 (#MD5)
密码 ＝ JS.运行 (“hex_md5”, 编辑框_密码.内容)
网页_访问 (“http://bbs.125.la/”, , , , cookie)
结果 ＝ 到文本 (网页_访问 (“http://bbs.125.la/member.php?mod=logging&action=login&loginsubmit=yes&infloat=yes&lssubmit=yes&inajax=1”, 1, “username=” ＋ 账号 ＋ “&password=” ＋ 密码 ＋ “&quickforward=yes&handlekey=ls”, cookie, cookie))
结果 ＝ 文本_取出中间文本 (结果, “<root><![CDATA[”, “<script type=”)
.如果 (结果 ＝ “”)
    信息框 (“登陆成功”, 0, , )
    结果 ＝ 到文本 (网页_访问 (“http://bbs.125.la/plugin.php?id=dsu_paulsign:sign”, 0, , cookie, ))
    组合框_积分.插入项目 (0, 文本_取出中间文本 (结果, #积分前, #积分后), )
    组合框_积分.插入项目 (1, “用户组：” ＋ 文本_取出中间文本 (结果, #用户组前, #用户组后), )
    组合框_积分.现行选中项 ＝ 0
    formhash ＝ 文本_取出中间文本 (结果, “formhash=”, #formhash)
    UID ＝ 文本_取出中间文本 (结果, #uid前, #uid后)
    结果 ＝ 到文本 (网页_访问 (“http://bbs.125.la/home.php?mod=spacecp&ac=credit&showcredit=1&inajax=1&ajaxtarget=extcreditmenu_menu”, 0, , cookie))
    调试输出 (结果)
    正则.创建 (“[0-9]*[\u4e00-\u9fa5]”, 结果, 假, 真, 真, )
    .如果真 (寻找文本 (结果, “您需要先登录才能继续本操作”, , 假) ＝ -1)
        .计次循环首 (正则.取匹配数量 (), i)
            加入成员 (账户信息, 正则.取匹配文本 (i, ))
        .计次循环尾 ()
        组合框_积分.插入项目 (1, “交易币：” ＋ 账户信息 [4], )
        组合框_积分.插入项目 (1, “好评：” ＋ 账户信息 [7], )
        组合框_积分.插入项目 (1, “精币：” ＋ 账户信息 [10], )
        组合框_积分.插入项目 (1, “诚信度：” ＋ 账户信息 [14], )
        组合框_积分.插入项目 (1, “荣誉度：” ＋ 账户信息 [17], )
    .如果真结束

.否则
    信息框 (结果, 0, , )
.如果结束

@科锐