易语言对象方法调用VBS命令创建快捷方式

创建程序快捷方式 (“C:\Users\Administrator\Desktop\asd.exe”)

.版本 2

.子程序 创建程序或文件快捷方式, 逻辑型, , 通过调用易语言对象方法创建程序或文件lnk快捷方式,调用VBS命令
.参数 程序或文件路径, 文本型, , 必须指向存在的程序或文件,例如:(c:\abc.exe 或 c:\abc.txt)
.参数 快捷方式输出目录, 文本型, 可空, 创建的快捷方式输出目录,例如:(d:\),默认使用程序自身目录,留空则为默认值
.参数 快捷方式文件名称, 文本型, 可空, 快捷方式名称,不用带lnk扩展名,例如:(abc),默认使用程序自身名称,留空则为默认值
.局部变量 objShell, 对象
.局部变量 objShellLink, 对象
.局部变量 Returns, 逻辑型
.局部变量 提取程序目录, 文本型
.局部变量 提取文件名称一, 文本型
.局部变量 提取文件名称二, 文本型

Returns ＝ 假
.如果真 (文件是否存在 (程序或文件路径) ＝ 假)
    返回 (假)
.如果真结束
提取程序目录 ＝ 取文本左边 (程序或文件路径, 倒找文本 (程序或文件路径, “”, , 假))
提取文件名称一 ＝ 取文本右边 (程序或文件路径, 取文本长度 (程序或文件路径) － 取文本长度 (提取程序目录))
提取文件名称二 ＝ 取文本左边 (提取文件名称一, 倒找文本 (提取文件名称一, “.”, , 假) － 1)
.如果真 (是否为空 (快捷方式输出目录) 或 快捷方式输出目录 ＝ “”)
    快捷方式输出目录 ＝ 提取程序目录
.如果真结束
.如果真 (是否为空 (快捷方式文件名称) 或 快捷方式文件名称 ＝ “”)
    快捷方式文件名称 ＝ 提取文件名称二
.如果真结束
objShell.创建 (“Wscript.Shell”, )  ' 创建对象
objShellLink ＝ objShell.对象型方法 (“CreateShortcut”, 快捷方式输出目录 ＋ 快捷方式文件名称 ＋ “.lnk”)  ' 写出lnk文件
objShellLink.写属性 (“TargetPath”, 程序或文件路径)  ' 程序文件
' objShellLink.写属性 (“Arguments”, “参数”)  ' 参数,没有请留空
objShellLink.对象型方法 (“Save”, )  ' 保存对象
.如果真 (文件是否存在 (快捷方式输出目录 ＋ 快捷方式文件名称 ＋ “.lnk”))
    Returns ＝ 真
.如果真结束
返回 (Returns)

@hmyroot