易语言树型框项目进入编辑状态源码

易语言树型框项目进入编辑状态源码

.版本 2
.支持库 iext

.程序集 窗口程序集_启动窗口

.子程序 _按钮1_被单击

树型框进入编辑 (树型框1.取窗口句柄 (), 树型框1.现行选中项 ＋ 1)

.子程序 树型框进入编辑, 整数型, 公开
.参数 树型框句柄
.参数 项目索引, , , 1 为项目一，2 为项目二，如此类推。

项目索引 ＝ 索引取句柄 (树型框句柄, 项目索引)
返回 (SendMessage (树型框句柄, 4366, 0, 项目索引))  ' #TVM_EDITLABEL=4366

.子程序 索引取句柄, 整数型
.参数 树型框句柄
.参数 项目索引
.局部变量 父项目
.局部变量 子项目, 整数型
.局部变量 数值, 整数型
.局部变量 完成, 逻辑型
.局部变量 计次, 整数型
.局部变量 句柄组, , , "0"

清除数组 (句柄组)
重定义数组 (句柄组, 假, 取项目数 (树型框句柄))
子项目 ＝ SendMessage (树型框句柄, 4362, 0, 0)  ' 先取第一个根
.判断循环首 (子项目 ≠ 0)
    计次 ＝ 计次 ＋ 1
    句柄组 [计次] ＝ 子项目
    数值 ＝ 子项目
    子项目 ＝ SendMessage (树型框句柄, 4362, 4, 子项目)  ' 取第一个子
    .如果真 (子项目 ＝ 0)  ' 取子取不到，就取兄弟
        子项目 ＝ SendMessage (树型框句柄, 4362, 1, 数值)  ' 取子的兄弟
        ' 找到了兄弟就直接到循环尾，否则进入下面的循环找父项目
        .判断循环首 (子项目 ＝ 0)
            父项目 ＝ SendMessage (树型框句柄, 4362, 3, 数值)  ' 退回上一级
            .如果真 (父项目 ＝ 0)
                完成 ＝ 真
                跳出循环 ()
            .如果真结束
            数值 ＝ 父项目
            子项目 ＝ SendMessage (树型框句柄, 4362, 1, 父项目)  ' 取父的兄弟
        .判断循环尾 ()
    .如果真结束
    .如果真 (完成)
        跳出循环 ()
    .如果真结束

.判断循环尾 ()
.如果真 (取数组成员数 (句柄组) ≥ 项目索引)
    返回 (句柄组 [项目索引])
.如果真结束
返回 (-1)

.子程序 取项目数, 整数型, 公开, 返回树型框中所有项目的数目。
.参数 树型框句柄

返回 (SendMessage (树型框句柄, 4357, 0, 0))  ' #TVM_GETCOUNT=4357

@iouioupp